WSUS Update Check

Das folgende Batch Skript prüft nach dem ausführen des Skriptes innerhalb der nächsten zehn Minuten, ob neue Updates zur Verfügung stehen.

Speichern Sie das folgende Skript in einer Datei mit der Endung .bat und führen es aus.

@echo off
REM
REM Der AutoUpdate Client prueft nach dem ausfuehren des Skriptes
REM innerhalb der naechsten zehn Minuten, ob neue Updates zur Verfuegung stehen
 
REM Prfen, ob das Program REG.EXE vorhanden ist
if EXIST %systemroot%\system32\REG.EXE goto WEITER
 
echo Das Skript kann nicht ausgefuehrt werden, weil das Programm
echo %systemroot%\system32\REG.EXE fehlt!
echo Sie finden dieses Tool auf Ihrer Windows 2000 CD im Archiv
echo \Support\Tools\support.cab.
 
goto ENDE
 
:WEITER
echo Dienst "Automatische Updates" stoppen...
%systemroot%\system32\net stop wuauserv 2>nul
 
 
echo Registry-Werte aendern ...
 
REM "LastWaitTimeout" loeschen, wenn nicht vorhanden Fehlermeldung
REM unterdruecken (mit "2>null")
%systemroot%\system32\REG DELETE "HKLM\Software\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update" /v LastWaitTimeout /f 2>null
 
%systemroot%\system32\REG ADD "HKLM\Software\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update" /v AUState /t REG_DWORD /d 2 /f
 
 
REM AutoUpdate-Dienst wieder starten
%systemroot%\system32\net start wuauserv
 
if errorlevel 2 goto ERR_SERVICEDISABLED
goto ALLESKLAR
 
:ERR_SERVICEDISABLED
echo -------------------------------------------------------------
echo Hinweis: Der Dienst "Automatische Updates" ist wahrscheinlich
echo deaktiviert. Starten Sie "services.msc" und setzen Sie hier
echo seinen Starttyp auf "manuell".
echo -------------------------------------------------------------
goto ENDE
 
:ALLESKLAR
echo ------------------------------------------------------------
echo Die Registry-Einstellungen wurden zurckgesetzt und der
echo AutoUpdate-Dienst neu gestartet.
echo In den naechsten zehn Minuten sollte der Dienst seinen
echo Server ansprechen, um nach neuen Updates zu suchen.
echo ------------------------------------------------------------
 
:ENDE
pause